#define LOWER_FLOOR_PLANE -100 // first plane for lower floors
#define MAIN_FLOOR_DISTANCE 9    // "distance" from camera

// create new/obj/lowerplane(1), new/obj/lowerplane(2), etc. as globals, and add to client.screen at login
obj/lowerplane
    appearance_flags = PLANE_MASTER | NO_CLIENT_COLOR
    plane = LOWER_FLOOR_PLANE
    screen_loc = "CENTER"   // so it can be added to client.screen
    New(z_delta)    // how many levels down is this?
        plane = initial(plane) - (z_delta-1)
        color = list("#d00", "#0d0", "#00d", "#000d", "#2222")
        transform = matrix(MAIN_FLOOR_DISTANCE / (z_delta+MAIN_FLOOR_DISTANCE), MATRIX_SCALE)
var/list/lowerplanes = new

atom/plane = FLOAT_PLANE

// the object that has the actual turf vis_contents
obj/lowerfloor
    appearance_flags = KEEP_TOGETHER
    vis_flags = VIS_INHERIT_LAYER

obj/floorpost
    vis_flags = VIS_HIDE
    layer = TURF_LAYER-0.5

    proc/Fill()
        var/X=x, Y=y, Z=z
        var/X0=max(X-1,1), Y0=max(Y-1,1)
        var/X1=min(X+8,world.maxx), Y1=min(Y+8,world.maxy)
        var/turf{T1; T2}
        var/P = LOWER_FLOOR_PLANE
        // offset this to line up with the southwest-most turf in visual contents
        transform = matrix(32*(X0-X), 32*(Y0-Y), MATRIX_TRANSLATE)

        // add a dummy object at the northeast corner so the engine knows to keep this post in view
        var/obj/dummy = new
        dummy.icon = null
        dummy.transform = matrix(32*(X1-X), 32*(Y1-Y), MATRIX_TRANSLATE)
        vis_contents += dummy

        while(--Z > 0)
            var/obj/lowerfloor/O = new
            O.plane = P--
            vis_contents += O
            T1 = locate(X0,Y0,Z)
            T2 = locate(X1,Y1,Z)
            O.vis_contents = block(T1,T2)
            // look for lower floors we might need
            if(!(locate(/obj/floorpost) in locate(X,Y,Z))) break

proc/FillSpaces()
    var/X,Y,Z
    var/turf/T
    var/obj/floorpost/FP
    var/list/posts = new
    for(var/turf/openspace/O)
        if((Z=O.z) <= 1) continue
        X=O.x; Y=O.y
        T = locate(((X-1)&~7)+1, ((Y-1)&~7)+1, Z)
        if(!T) continue
        FP = locate() in T
        if(!FP)
            FP = new/obj/floorpost(T)
            posts[FP] = null
    for(FP in posts) FP.Fill()

world/New()
    ..()
    FillSpaces()

mob/Login()
    ..()
    for(var/i in 1 to world.maxz-1)
        if(i > lowerplanes.len) lowerplanes += new/obj/lowerplane(i)
        client?.screen += lowerplanes[i]