#define FALSE 0
#define TRUE 1

mob
    Player
        icon_state = "player"
        verb/Say(var/phrase as text)
            //First, display what you've said
            view(4,src) << "<b>[src]:</b> [phrase]"
            //Then, for every NPC around you
            for(var/mob/NPCS/F in oview(4,src))
                //Have that NPC evaluate your phrase,
                //and pass in your name too in case they should respond
                F.eval_phrase(phrase,src.name)
    NPCS
        var
            //This is a list of Questions that this NPC may process
            list/Question/questions
        proc
            //This is how we will actually process what is said,
            // and respond to the source
            eval_phrase(var/phrase,var/source)
                //First we loop through our questions
                for(var/Question/P in src.questions)
                    //We ask each of our questions to evaluate your phrase
                    if(P.eval_phrase(phrase,src))
                        //If your phrase turned out to signal the question,
                        //the question will give us the proper response
                        var/response = P.response()

                        //Then we will pass this response to our NPC in case it has its own
                        //behavior for it
                        respond(response,source)

                        break
            respond(var/response,var/toWhom)
                world << "[response], [toWhom]"
        //Based on the above definition, we can define any NPC
        //to respond to questions by
        //1. Adding a predefined Question to their questions variable
        //2. Thats it.  We can also modify respond(var/response,var/toWhom)
        //   if we wnat to control further how they respond.
        Fairy
            icon_state = "fairy"

            //In this case, we have defined what FairyHello() accepts as a question
            //and response elsewhere
            questions = list(new /Question/FairyHello())

            //Ignore this, this is for my testing
            New()
                .=..()
                name = pick(names)

            //In this case, a fairy will take the questions proper response
            //and add your name to it
            respond(var/response,var/toWhom)
                view(4,src) << "[response],[toWhom]"
        //Based on the above definition,
        //this is how we would make an NPC that responds differently
        Ogre
            icon_state = "ogre"
            //We give it different questions, that we define elsewhere
            questions = list(new /Question/GenericHello(), new /Question/OgreGoodbye())
            //We change how it responds, slightly
            respond(var/response,var/toWhom)
                view(6,src) << "Ogre says [response] [toWhom]"
            //And thats it
        Ghoul
            questions = list(new /Question/GenericHello())

            //In this one we dont define response, so it will have a default response

//Now for the definitions of our Question objects and everything else really
Question
    //You will see what PhraseTypes are under this. Basically,
    //they are a class of phrases that are similar, such as
    //Hello dude
    //Hey man
    //Hows it going
    var/PhraseType/question
    var/PhraseType/response
    proc
        //The question is asked earlier to evaluate
        //if your phrase merits a response from it
        //To do this, it asks its phrase type to check
        //if your phrase was considered 'one of its kinds of phrases'
        eval_phrase(var/phrase,var/name)
            return src.question.eval_phrase(phrase,name)
        response()
            return src.response.response()
    FairyHello
        question = new /PhraseType/Hellos()
        response = new /PhraseType/Hellos()
    GenericHello
        question = new /PhraseType/Hellos()
        response = new /PhraseType/Hellos()
    OgreGoodbye
        question = new /PhraseType/Goodbye()
        response = new /PhraseType/Goodbye()
//This is a grouping of the phrase definitions listed after this
PhraseType
    var
        list/phrases = list()
    proc
        eval_phrase(var/phrase,var/name)
            if(!phrases)
                return FALSE
            for(var/Phrase/P in phrases)
                if(P.eval_phrase(phrase,name))
                    return TRUE
            //Default case
            return FALSE
        response()
            var/Phrase/phrase = pick(phrases)
            return phrase.response()

    Hellos
        phrases = list(new /Phrase/Hello, new /Phrase/WhatsUp, new /Phrase/HowsItGoing, new /Phrase/HowAreYou)
    Goodbye
        phrases = list (new /Phrase/Goodbye)
//A phrase just represents a set of similar phrase beginnings
//and all of their equivalent endings
Phrase
    var
        list/synonyms
        list/endings
    Hello
        synonyms = list("hi","hello","hey","wassup")
    WhatsUp
        synonyms = list("what's","whats","what is","what")
        endings = list("up","going on","happening")
    HowsItGoing
        synonyms = list("hows","how is")
        endings = list("it going")
    HowAreYou
        synonyms = list("how")
        endings = list("are you","are ye","is it going")
    Goodbye
        synonyms = list("Goodbye","Cya","Bye","Ciao pues")
    //This is where the real phrase analyzing comes in
    proc/eval_phrase(var/phrase,var/name)
        phrase = lowertext(phrase)
        var/hasPhrase = FALSE
        //First, we check if your phrase contains the beginning
        //of the phrase we are looking for
        //Example: you say "what is up"
        //This phrase is: WhatsUp
        //This phrase first looks for "what's", but you didn't say that
        //Then it looks for "whats", but you didn't say that
        //Then it looks for "what is", and you did say that
        for(var/word in synonyms)
            var/position = findtext("[phrase]","[word]")
            //If we find "what is" from our example,
            //we will now look for a proper ending after "what is"
            //Proper endings would be "up","going on", or "happening"
            if(position)
                //If there are no endings at all for this phrase
                if(!endings)
                    //Then we must have found the phrase
                    hasPhrase = TRUE
                    break
                //Else, look for our ending
                for(var/ending in endings)
                    //This is the part of the string (start-end)
                    //where the ending will be found
                    //Start is basically right after the first chunk
                    //of the phrase, in our example case itd be after "what is"
                    var/start = position + lentext(word)
                    var/end = start + lentext(ending) + 1
                    if(findtext(phrase,ending,start,end))
                        hasPhrase = TRUE
                        break
        if(hasPhrase)
            //If we found the phrase, just made sure the persons name was used
            if(findtext("[phrase]","[name]"))
                return TRUE
        return FALSE
    //If someone is asking for a response made from this phrase,
    //just pick a phrase beginning
    //and match it with an ending
    proc/response()
        var/response = pick(synonyms)
        response += " " + pick(endings)
        return response