Adding Commas

ID:152950
 
Jun 18 2005, 5:14 am
I hate the way BYOND uses Scientific Notation when you have numbers 7 or more digits. Thats why I made a proc to convert all numbers to text so it wouldnt do that. But its kinda hard to tell how much you have at a glance if its a large number. I need a way to input commas into the text. Any suggestions?
Jun 18 2005, 5:35 am
 
proc
    Add_Comma(N)
        N=num2text(N,10)
        if(lentext(N)<4)return N
        var {Final;At;Temp}
        for(var/i=lentext(N),i>0,i--)
            At++
            if(At==4)
                At=1;Temp+=","
            Temp+=copytext(N,i,i+1)
        for(var/i=lentext(Temp),i>0,i--)
            Final+=copytext(Temp,i,i+1)
        .=Final
Jun 18 2005, 7:40 pm (Edited on Jun 18 2005, 8:26 pm)
In response to Crashed
Here's my take on it (slightly cleaner IMO). This one assumes you've already converted to text:

proc/commas(T)
    // Account for decimals
    var/result=""
    var/dotpos=findtext(T,".")
    if (dotpos)
        result=copytext(T,dotpos)
        T=copytext(T,1,dotpos)
    // Insert commas
    var/addednum=0
    while(length(T))
        if (addednum && T!="-" && T!="+") result=","+result
        addednum=1
        result=copytext(T,max(1,length(T)-2))+result
        T=copytext(T,1,max(1,length(T)-2))
    return result


Has been tested, and works fine.

Edit: Now supports decimal numbers and negative numbers. Commas are not added to the decimal portion.
Jun 18 2005, 8:04 pm
In response to Crispy
Test it with -100.23 :)
Jun 18 2005, 8:11 pm
In response to Theodis
Bah, I forgot about decimals. =P

In my defence, Crashed did too...

Anyway, I'll fix that.
Jun 19 2005, 8:31 am
My kunarklib library has the k_instert_commas() proc, if you want to see it.

it works like a charm. Just use it for display only. I use it in Drugwars if you want to see it in action.