Squad Ranks

ID:162215
 
Feb 11 2008, 12:35 am
Well, I want to add ranking officers in my game, and I want it to be automatic. Depending on how many kills and death you have, depends on your squad rank.

Example:
I have 14 kills, and 2 deaths, but someone else had 14 kills, and one death. That would make their kills and deaths record better then my own. So they would be a higher rank than me.


This is for my bleach game, and the ranking officers are for the shinigami.

Could someone show me a simple code for it so I could see how I can approach making it, so I can learn how to do it.
Feb 11 2008, 1:03 am
Make it a ratio of kills to deaths.
Whenever a player is killed put this proc in:
mob/proc/
    RatioCheck()
        if(!src.kills||!src.deaths) src.ratio=src.kills
        else src.ratio=src.kills/src.deaths
Feb 11 2008, 1:39 am
In response to Saucepan Man
Saucepan Man wrote:
Make it a ratio of kills to deaths.
Whenever a player is killed put this proc in:
> mob/proc/
>   RatioCheck()
>       if(!src.kills||!src.deaths) src.ratio=src.kills
>       else src.ratio=src.kills/src.deaths
>


How would I use this to make it so Squad ranks are automatic? I want it to be so if it changes, the persons rank could possibly change.

Say like I am the 4th officer of my squad, then someone in my squad dies 3 times. So his new deaths and kills is say, 12 kills, and 7 deaths. Then I have something like 12 kills and 5 deaths. He was the 3rd officer, but now since I am doing better in kills and deaths, I would take his place, and he would get knocked back a rank (Maybe 2).
Feb 11 2008, 1:56 am (Edited on Feb 11 2008, 2:19 am)
In response to DWX123
You'd need a list of people in the squad. Every time someone gets a kill or a death, sort the list using quicksort or something. Then, assign ranks based on people's positions in the list:
proc/quicksort_ratio(list/squad) //A quicksort proc, adapted for comparing a var called 'ratio'
    if(!squad)return //If there is no list, stop now.
    if(squad && squad.len == 1) return squad //If there is only 1 item, no sorting is required.
    var/list //Make three lists. 
        less = list() //This list has players with a worse ratio than the 'pivot'
        equal = list() //This list has players with the same ratio as the 'pivot'
        greater = list() //This list has players with a better ratio than the 'pivot'
    var/mob/pivot = squad[1] //The 'pivot' is any member of the squad. It's just something to compare the others to.
    for(var/mob/m in squad) //For each member of the squad
        if(m.ratio < pivot.ratio)less += m  //If they have a worse ratio, put them in the 'less' list.
        else if(m.ratio > pivot.ratio)greater += m //If they have a better ratio, put them in the 'greater' list.
        else equal += m //otherwise put them in the 'equal' list.
    return quicksort_ratio(greater)+equal+quicksort_ratio(less)
    //Sort each list, having the better ratios at the top.

proc/assign_new_ranks(list/squad) //The proc for giving new ranks
    if(!squad)return
    squad = quicksort_ratio(squad) //Sort the squad list
    for(var/r in 1 to squad.len) //Loop through the list
        squad[r] << "You are now rank [r] in your squad!" //Squad[r] refers to the player who is in the r'th position. So if r == 4, squad[r] is the 4th in the list. 
        //Do rank stuff here
Feb 11 2008, 2:10 am
In response to Hazman
Arrggghh... It's so confusing. I have no idea what that code you posted does, or means. =\
Feb 11 2008, 2:15 am
In response to DWX123
Basically the top bit is a quicksort proc which sorts the list into three lists (bigger, smaller, equal), and then sorts those lists, and then those lists etc. until there is only 1 item in each list. It then sticks the list back together in the right order. There's a better explanation on the wiki page I linked to.

The second bit sorts the squad list you give it, then loops through each player in the squad and tells them their new rank. It does this by counting from 1 up to the number of players (for(var/r in 1 to squad.len)) and then telling the player with that rank what their rank is.

[EDIT] I've put some comments in the code so hopefully it is a bit easier to understand.
Feb 11 2008, 2:19 am
In response to Hazman
Hazman wrote:
Basically the top bit is a quicksort proc which sorts the list into three lists (bigger, smaller, equal), and then sorts those lists, and then those lists etc. until there is only 1 item in each list. It then sticks the list back together in the right order. There's a better explanation on the wiki page I linked to.

The second bit sorts the squad list you give it, then loops through each player in the squad and tells them their new rank. It does this by counting from 1 up to the number of players (for(var/r in 1 to squad.len)) and then telling the player with that rank what their rank is.

So will this give everyone in the squad a rank, or just the top [insert number here]. I only want tohave 6 ranking officers in each squad, the rest of them will just be members.
Feb 11 2008, 2:22 am
In response to DWX123
I also get errors with the code you gave me.

Squadranks.dm:10:error:m.ratio:undefined var
Squadranks.dm:10:error:pivot.ratio:undefined var
Squadranks.dm:11:error:m.ratio:undefined var
Squadranks.dm:11:error:pivot.ratio:undefined var
Squadranks.dm:8:pivot :warning: variable defined but not used
Feb 11 2008, 2:22 am
In response to DWX123
That will give everyone a rank, but you can easily restrict it to the top six by changing the for() loop in the give rank proc:
//Blah blah blah
for(var/r in 1 to squad.len)
  //Blah blah blah

 ||
 \/

//Blah blah blah
var/officers = min(6,squad.len) //If there less than six members, all of them will be officers.
for(var/r in 1 to officers)
  //Blah blah blah
Feb 11 2008, 2:23 am
In response to DWX123
That's because you need to actually have a 'ratio' variable for each player. You'll also need to update it every time they get a kill or death, and run the proc I gave you as well.
Feb 11 2008, 2:37 am
In response to DWX123
Dude, I have no idea what you wanted.
I still don't really get it. Never played a Bleach game, never seen a Bleach Episode, never read any Bleach manga.
You shouldn't make posts assuming people know what youre talking about. :S

Hazman wrote:
That's because you need to actually have a 'ratio' variable for each player. You'll also need to update it every time they get a kill or death, and run the proc I gave you as well.

At least I was of help still.